LCD顯示網(wǎng)址和電話
;本實戰(zhàn)的目的是讓大家進(jìn)上步熟悉查表程序的用法，MCD1配套LCD的讀寫方法
;程序文件名“MCD-LCD2.ASM"
;程序清單如下:
;************************************
PCL     EQU 2H   ;定義程序存儲器低字節(jié)地址
STATUS  EQU 3H   ;定義狀態(tài)寄存器地址
PORTA   EQU 5H   ;定義RA口數(shù)據(jù)寄存器地址
PORTC   EQU 7H   ;定義RC口數(shù)據(jù)寄存器地址
TRISA   EQU 85H  ;定義RA口方向控制寄存器地址
TRISC   EQU 87H  ;定義RC口方向控制寄存器地址
ADCON1  EQU 9FH  ;定義ADC模塊控制寄存器1的地址
;********************
Z       EQU 2    ;定義0狀態(tài)位的位地址
RP0     EQU 5    ;定義頁選位RP0的位地址
;*********************
RS EQU 1         ;LCD寄存器選擇信號腳定義在RA.1腳
RW EQU 2         ;LCD讀/寫信號腳定義在RA.2腳
E  EQU 3         ;LCD片選信號腳定義在RA.3腳
COUNT EQU 24H    ;定義計數(shù)寄存器地址
TMP1  EQU 25H    ;定義臨時寄存器地址
;**********************
  ORG 000H
  NOP              ;放置一條ICD必需的空操作指令
  GOTO MAIN
  ORG 0008H
;******************************************************
TABLE                     ;取第一行的顯示碼
           ADDWF PCL,1    ;地址偏移量加當(dāng)前PC值
           RETLW 20H      ;空格
           RETLW 57H      ;W
           RETLW 57H      ;W
           RETLW 57H      ;W
           RETLW 2EH      ;.
           RETLW 50H      ;P
           RETLW 49H      ;I
           RETLW 43H      ;C
           RETLW 31H      ;1
           RETLW 36H      ;6
           RETLW 2EH      ;.
           RETLW 43H      ;C
           RETLW 4FH      ;O
           RETLW 4DH      ;M
           RETLW 20H      ;空格
           RETLW 20H      ;空格
           RETLW 00H
;-------------------- ----------------------------------
TABLE1                               ;取第二行的顯示碼TEL0755 27528531
            ADDWF PCL,1              ;地址偏移量加當(dāng)前PC值                                                  
     RETLW 54H       ;T
     RETLW 45H       ;E                            
     RETLW 4CH       ;L
     RETLW 30H       ;0
     RETLW 37H       ;7
     RETLW 35H       ;5
     RETLW 35H       ;5
     RETLW 20H       ;空格
     RETLW 32H       ;2
            RETLW 37H                   ;7
            RETLW 35H                   ;5
            RETLW 32H                   ;2
            RETLW 38H                   ;8
            RETLW 35H                   ;5
            RETLW 33H                   ;3
            RETLW 31H                   ;1
            RETLW 00H
;*******************************************************
MAIN

  BSF STATUS,RP0          ;定義RA口,RC口全部為輸出
  MOVLW 07H
  MOVWF ADCON1            ;設(shè)置RA口全部為普通數(shù)字IO口
  MOVLW 00H
  MOVWF TRISA
  MOVWF TRISC
  BCF STATUS,RP0

  CALL DELAY              ;調(diào)用廷時,剛上電LCD復(fù)位不一定有PIC快
  MOVLW 01H
  MOVWF PORTC             ;清屏
  CALL ENABLE
  MOVLW 38H
  MOVWF PORTC             ;8位2行5x7點陣
  CALL ENABLE
  MOVLW 0FH               ;顯示器開、光標(biāo)開、閃爍開
  MOVWF PORTC
  CALL ENABLE
  MOVLW 06H               ;文字不動，光標(biāo)自動右移
  MOVWF PORTC            
  CALL ENABLE
  MOVLW 80H
  MOVWF PORTC             ;顯示位置
  CALL ENABLE

  CALL WRITE1             ;調(diào)用送第一行數(shù)子程序“WWW.PIC16.COM"
  MOVLW 0C0H
  MOVWF PORTC            ;第一行的位置      
  CALL ENABLE
  CALL WRITE2            ;調(diào)用送第二行數(shù)子程序“TEL0755 27528531"
  MOVLW 0C2H
  MOVWF PORTC             ;第二行的位置
  CALL ENABLE
  GOTO $
 
;***********************
WRITE1
  CLRF COUNT          ;送第一行數(shù)字程序
WRITE_A
  MOVFW COUNT
  CALL TABLE
  MOVWF TMP1
  CALL WRITE3
  INCF COUNT,1
  MOVFW TMP1
  XORLW 00H
  BTFSS STATUS,Z
  GOTO WRITE_A
  RETLW 0
;*************************
WRITE2                 ;送第二行數(shù)子程序
  CLRF COUNT
WRITE2_A
  MOVFW COUNT
  CALL TABLE1
  MOVWF TMP1
  CALL WRITE3
  INCF COUNT,1
  MOVFW TMP1
  XORLW 00H
  BTFSS STATUS,Z
  GOTO WRITE2_A
  RETLW 0
;**************************
WRITE3                 ;送數(shù)據(jù)到LCD子程序
  MOVWF PORTC
  BSF PORTA,RS
  BCF PORTA,RW
  BCF PORTA,E
  CALL DELAY
  BSF PORTA,E
  RETLW 0
;*******************************************
ENABLE
  BCF PORTA,RS         ;寫入控制命令的子程序
  BCF PORTA,RW
  BCF PORTA,E
  CALL DELAY
  BSF PORTA,E
  RETLW 0
;********************************************
DELAY                      
                             ;子程序名，也是子程序入口地址
       movlw   0ffh          ;將外層循環(huán)參數(shù)值FFH經(jīng)過W
       movwf   20h          ;送入用作外循環(huán)變量的20H單元
lp0    movlw   0ffh          ;將內(nèi)層循環(huán)參數(shù)值FFH經(jīng)過W
       movwf   21h           ;送入用作內(nèi)循環(huán)變量的21H單元
lp1    decfsz   21h,1         ;變量21H內(nèi)容遞減，若為0跳躍
       goto     lp1           ;跳轉(zhuǎn)到LP1處
       decfsz    20h,1         ;變量20H內(nèi)容遞減，若為0跳躍
       goto     lp0           ;跳躍到LP0處
       return                 ;返回主程序
       end                   ;源程序結(jié)束
;*****************************************************
;    進(jìn)入該實戰(zhàn)演練的工序流程如下:
;    1.創(chuàng)建源文件和編輯源文件;在此介紹一種不同于前面講的創(chuàng)建源文件的方法,用Windows附件中的”記事本”
;   這個為大家所熟知和好用的文件編輯器,并且可以方便的加入中文注釋.不過有兩點需要注意,一是注釋前面的
;   分號”;”必須用西文半角輸入;二是必須用”.asm”擴(kuò)展名存儲到事先建立的一個專用子目錄下.
;    2.打開MPLAB集成開發(fā)環(huán)境:首先在WINDOWS環(huán)境下,選用開始>程序>Microchip MPLAB>MPLAB命令,啟動MPLAB
;   并進(jìn)入MPLAB的桌面.
;    3.創(chuàng)建項目:選用菜單File>New或Project>New Project,在事先建立的一個專用子目錄下創(chuàng)建一個新項目,將
;   用記事本創(chuàng)建的源文件加入到該項目中.
;    4.建立項目中的目標(biāo)文件:選擇菜單Project >Build All(項目>建立所有文件),MPLAB將自動調(diào)用MPASM將項目
;   文件管理下的源文件(.asm)匯編成十六進(jìn)制的目標(biāo)文件(.hex).
;    5.ICD參數(shù)設(shè)置:通過菜單命令Project>Edit Project或者Option>Development Mode,將開發(fā)模式設(shè)置為
;   ”MPLAB ICD Debugger”,點擊OK按鈕,打開ICD的工作窗口,在調(diào)試階段,可以按照說明書圖2-10設(shè)置各項,但需注意
;   OSCILLATOR應(yīng)設(shè)置為XT方式,尤其需要說明的是，選中“Enable Debug Mode”（使能調(diào)試模式）選項，在向目
;   標(biāo)單片機(jī)燒寫機(jī)器碼程序時，會將調(diào)試臨控程序同時寫入單片機(jī)的指定程序存儲器區(qū)域，然后才允許用ICD方式調(diào)試。
;    6.電路設(shè)置:將演示板的S1全部拔到OFF，S13全部拔到OFF，S4,S5全部拔到OFF ，LCD對準(zhǔn)腳位插在演示板上，
;   將用于選擇頻率的插針跳線插到”XT OSC”位置上，板上93CXX、24CXX應(yīng)拿下。
;    7.向目標(biāo)單片機(jī)燒寫目標(biāo)程序:用戶在點擊功能按鈕”Program”向目標(biāo)單片機(jī)燒寫機(jī)器碼程序時,會等待一段時間，
;   并且在條狀的狀態(tài)信息欄中，出現(xiàn)提示信息。有一點需要引起注意，就是PIC16F87X單片機(jī)的FLASH程序存儲器的擦寫
;   周期是有限的，大約為1000次，應(yīng)盡量節(jié)省它的使用壽命。
;    8.運行和調(diào)試用戶程序和用戶電路:在各項參數(shù)設(shè)置好后,將ICD的工作窗口最小化,利用前面講的”運行及調(diào)試”中介
;   紹的幾種方法進(jìn)行調(diào)試.當(dāng)用自動單步方式調(diào)試時,建議臨時禁止廷時子程序發(fā)揮作用,具體的方法是,可在CALL DELAY指
;   令前添加一個分號,并且重新匯編一次.為了學(xué)習(xí)目的,在調(diào)試過程中可以人為地加入一些軟件漏洞(BUG)或硬件故障,來模
;   仿單片機(jī)端口引腳的片內(nèi)或片外故障.
;    9.定型燒寫目標(biāo)單片機(jī);經(jīng)過多次重復(fù)上述步驟的反復(fù)修改和調(diào)試,使得程序和電路在聯(lián)機(jī)狀態(tài)完全正常,這時可以進(jìn)行
;   定型燒寫,即將ICD窗口中的”Enable Debug Mode”(使能調(diào)試模式)選項消除,不再將調(diào)試臨控程序?qū)懭雴纹瑱C(jī)中.
;    10.獨立運行驗收:上一步中的燒寫過程完成后,即可將ICD模塊和ICD仿真頭(或演示板)之間的6芯電纜斷開,讓單片機(jī)在
;   演示板獨立運行,觀察實際效果.
;
;